You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 

43 lines
1.9 KiB

<document> = [govern], { block }
govern = <"govern">, ws, ( circle | role ), ws, name, <".">, cr, { cr }
<block> = resolution | <comment>
<resolution> = ( create | update | delete | convert | define | strike | elect |
appoint | unappoint),
<".">, { ws }
create = <"create">, ws, entity, ws, name, [ws, <"with">, ws, create-components]
update = <"update">, ws, entity, ws, name, ws, update-action-list
delete = <"delete">, ws, entity, ws, name
define = <"define policy">, ws, name, ws, <"as">, ws, name
strike = <"strike policy">, ws, name
elect = <"elect">, ws, name, ws, <"as">, ws,
[ "facilitator" | "secretary" | "rep link" ], ws, <"expiring">, ws,
#"\d{4}-\d{2}-\d{2}"
appoint = <"appoint">, ws, name, ws, <"to">, ws, name, { ws, <"with focus">,
ws, name }
unappoint = <"unappoint">, ws, name, ws, <"from">, ws, name
convert = <"convert">, ws, entity, ws, name, ws, <"into a">, ws, entity
comment = <"--">, comment-text, cr, { cr }
comment-text = #'[^\n]*'
<cr> = <"\n">
<text> = #"[^\"]*"
<update-action-list> = update-action, { ws <"and"> ws update-action }
<update-action> = add | remove | change-purpose | rename
add = <"add">, ws, component
remove = <"remove">, ws, component
change-purpose = <"change purpose to">, ws, name
rename = <"rename to">, ws, name
<ws> = <#'\s+'>
<entity> = anchor-circle | circle | role
anchor-circle = <"anchor circle">
circle = <"circle">
role = <"role">
<name> = <'"'>, text, <'"'>
<create-components> = component, { ws <"and"> ws component }
<component> = purpose | accountabilities | domains | cross-links
purpose = <"purpose">, ws, name
accountabilities = <"accountability">, ws, name | <"accountabilities">, ws,
name-list
domains = <"domain">, ws, name | <"domains">, ws, name-list
cross-links = <"cross-link">, ws, name | <"cross-links">, ws, name-list
<name-list> = name, { <",">, ws, name }